Je wilt graag e-mails versturen vanaf jouw website met ASP, op een goede en veilige manier? Bij Vevida kan dit eenvoudig.


Je kunt bij Vevida van twee componenten gebruik maken om met ASP/VBScript een e-mail te versturen: CDOSYS component (link 2) en ASPEMail.

Dit artikel richt zich op het gebruik van CDOSYS, in combinatie met authenticated SMTP en TLS-versleuteling. Deze twee voorwaarden zijn verplicht bij Vevida om van smtp.vevida.com gebruik te kunnen maken voor het versturen van een e-mail vanaf jouw website.

Standaard maakt CDOSYS gebruik van de in Windows ingebouwde “pick-up directory”, waar vanuit de IIS SMTP-service alle berichten verstuurt die daar worden geplaatst. Dit werkt bij Vevida niet. De configuratie van CDOSYS moet worden aangepast om van een SMTP-server gebruik te maken. Dit moet zijn:

smtp.vevida.com

Voor deze SMTP-server moet ook geconfigureerd zijn dat de verbinding met TLS versleuteld is. En er moet met een e-mailadres en wachtwoord op de SMTP-server worden ingelogd, dit heet SMTP-authenticatie. Dit draagt zorg voor een betere beveiliging van uw gegevens en een hogere zekerheid van de e-mailbezorging bij de ontvanger. Hiervoor is het CDO.Configuration object nodig.

Een voorbeeldfunctie in ASP/VBScript is:

<%@ Language=VBScript %>
<%
Sub send_eMail()
	Dim myMail, Fields, strFrom, strTo	 	 
	strFrom = "e-mailadres verzender"	 	 
	strTo = "e-mailadres ontvanger"
	
	' http://msdn.microsoft.com/en-us/library/ms526318(v=exchg.10).aspx
	' Its good practice to use the module constants defined in the
	' type library for the names. The full names are used here to
	' indicate that this is what is going on
	Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
	Const cdoSendUsingPort = 2
	Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
	Const cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
	Const cdoSMTPConnectionTimeout = "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
	Const cdoSMTPAuthenticate = "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
	Const cdoBasic = 1
	Const cdoSendUserName = "http://schemas.microsoft.com/cdo/configuration/sendusername"
	Const cdoSendPassword = "http://schemas.microsoft.com/cdo/configuration/sendpassword"
	' Use SSL for the connection (False or True)
	Const cdoSendTLS = "http://schemas.microsoft.com/cdo/configuration/smtpusessl"
	
	Set myMail = CreateObject("CDO.Message")
	Set myMail.Configuration = CreateObject("CDO.Configuration")
	Set Fields = myMail.Configuration.Fields

	' SMTP-configuratie
	With Fields
		.Item(cdoSendUsingMethod) = cdoSendUsingPort
		.Item(cdoSMTPServer) = "smtp.vevida.com"
		.Item(cdoSMTPServerPort) = 25
		.Item(cdoSMTPConnectionTimeout) = 10
		.Item(cdoSMTPAuthenticate) = cdoBasic
		.Item(cdoSendUserName) = "inlognaam verzender"
		.Item(cdoSendPassword) = "wachtwoord verzender"
		.Item(cdoSendTLS) = true
		.Update
	End With

	' Stel afzender, ontvanger, onderwerp en bericht in
	myMail.From = strFrom
	myMail.To = strTo
	myMail.Subject = "Dit is het onderwerp van mijn bericht."
	myMail.TextBody = "Dit is de tekst van mijn bericht."

	' Verstuur de e-mail
	myMail.Send

	' Verwijder de objecten
	Set Fields = nothing
	Set myMail.Configuration = nothing
	Set myMail = nothing
End Sub

%>

Verander “inlognaam verzender” met het e-mailadres van de verzender en “wachtwoord verzender” met het bijbehorende wachtwoord. Dit moet een in MyVevida aangemaakt e-mailaccount zijn.

Let op

Dit is een ASP Sub en dient als zodanig aangeroepen te worden:

<%@ Language=VBScript %>
<% send_eMail() %>

Door het verwijderen van de regels Sub send_eMail() en End Sub is dit eenvoudig in een bestaand ASP-script of formulier te verpakken.

Nota bene

Mocht u naar aanleiding van dit artikel een reactie hebben dan kunt u die via het onderdeel Support op MyVevida naar ons sturen.

Wat vond je van dit antwoord?

Bedankt voor je feedback!

Er is een fout opgetreden. Probeer het later opnieuw.